Prospectus for Data Analysis

Five percent of your lab grade is based upon this "prospectus."

You will submit two SPSS files (one hardcopy and one via computer) to fulfull this requirement.

  1. Via computer, submit a copy of your data file containing every variable your study would generate.
    • Don't just put in the sum total of a survey, enter the individual questions and have SPSS do the necessary recodes and calculations.  If you don't actually have access to the psychological instrument you're using, that's ok, just make a best guess regarding the number and nature of the items and put them in your data set.
    • Variable and Value Labels should be added where appropriate to aid in the interpretation of the data set.  When there are long strings of variables (say a 200 item questionnaire) it is only necessary to provide detailed labels for the first entry.
  2. Submit a hard copy of your syntax file containing every statistical procedure needed to calculate/refine your variables as well as all the descriptive and inferential statistics any professional in the field would need to fully analyse and publish this piece of research. Profesionals are also normally inquisitive and would look at rational analyses that their data provide them with even if these analyses are NOT part of their main hypotheses.  I believe your life will be simplified if you use comments liberally throughout the syntax file.  You may also add written comments.
    • Ask yourself--what would the APA Manual want to be extracted from this data set?
    • Don't make me figure anything out--explain what everything is for.
    • Please circle all comments, so they're easy to see.
    • Don't write in red--that's my color:)
I've appended a syntax file of mine, that you've seen before, to remind you of how comments can be used:

Comment  Comments in syntax files can be very useful.  Begin a Comment with
    "Comment." (without the ".") Indenting each line, as I do, is a nice
    visual touch to make comments easy to read.  The Comment will continue until
    you enter a blank line.  I have a feeling that a period at the end of
    the comment is a good, but maybe not necessary, idea.  WARNING, a
    period at the end of any line in a Comment ends the Comment and any
    lines that follow won't be recognized as a Comment.

 
Comment  WARNING--WARNING
    Run this syntax file only once on your data set.  The factor analysis I've
    put in will keep generating duplicate strings of new variables every time
    it is run--annoying, but true.  Put any syntax entries that you may
    have in a separate file.

Comment This extracts our questions 1-10.

do repeat x = q1 to q10/y = q26 to q35/z = our1 to our10.
IF (ourquest = 1) z = x .
if (ourquest = 2) z = y.
end repeat.

Comment  This extracts their questions 1-25.

do repeat x = q1 to q25/y = q11 to q35/z = their1 to their25.

IF (ourquest = 1) z = y.
if (ourquest = 2) z = x.
end repeat.
EXECUTE .

Comment  This recodes into the same variables (horrors)--This is OK here, trust me,
    because the vaviables are  dynamically created by the do repeats above--
    the dynamic creation means that even if you run this syntax file multiple times,
    the recoded variables will always be correct. The recode reverses responses
    on negatively worded items.

RECODE
our1 our5 our6 our8 our9 our10 their2 their4 their6 their8 their10
their12 their14 their16 their18 their20 their22 their24
their25 (1=5)(2=4)(3=3)(4=2)(5=1).
EXECUTE.

Comment  The factor scores for the paranormal (their) survey will be
    easy to calculate, each will simply be the mean of the items that
    the authors of the survey we used said constitute each factor. The
    names of the variables give an indication of what each score
    relates to.  Take a look at the relevant survey questions to
    flesh out the concept. (Note if you visited this page before
    and ran the factor analysis that was here earlier in the break,
    that's legal too, not to worry).  We also calculated a total paranormal score
    to play with.

compute relig = mean(their1 to their4).
compute psi = mean(their5 to their8).
compute witch = mean(their9 to their12).
compute supers = mean(their13 to their15).
compute spirit = mean(their16 to their19).
compute monster = mean(their20 to their22).
compute precog = mean(their23 to their25).
compute totpara = mean(their1 to their25).
execute.

Comment    This factor analysis creates 3 factor scores on our survey
    regarding attitudes regarding rules and laws.  The terms in
    parentheses are what the factors will be called in your data
    set. For example fac1_1 would be the first factor score in the
    first (only) factor analysis in your program (in this case
    our survey on rules and laws).

Comment Roughly, the factors mean the following:
     1 (fac1_1) Deals with fear of being caught for a transgression
     2 (fac2_1) Deals with general attitudes about rules and laws
     3 (fac3_1) Deals with attitudes about specific rules and laws.

FACTOR
  /VARIABLES our1 to our10
  /PRINT INITIAL EXTRACTION ROTATION
  /PLOT EIGEN
  /CRITERIA factors(3) ITERATE(25)
  /EXTRACTION PC
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .

**Comment--this calculates an overal score for our items.

compute totallaw=mean(our1 to our10).
execute.

***Comment--don't worry about what this does--trust me, you should do it.

recode write_lt to box_rt (missing =0).
execute.

***Comment--this calculates a left and right hand score and then integrates them into an overall
   Edinburgh Score.

compute left= (write_lt+draw_lt+throw_lt+sciss_lt+knife_lt+tooth_lt+spoon_lt+broom_lt+match_lt+box_lt)*(-1).
compute right= (write_rt+draw_rt+throw_rt+sciss_rt+knife_rt+tooth_rt+spoon_rt+broom_rt+match_rt+box_rt)*(1).
compute handed=left + right.
 

***Comment--Finally, this extracts the birth month from the birth date and puts it into a new variable.

compute monthnum=xdate.month(birthday).
execute.